***SIMBO-C.
***Konstruktion_Stand: 14.11.2008.
***Autor: Marco Streibelt, Berlin.

***Erlaeuterung.
***Codeschema immer von oben nach, beginnend bei 1 (außer anders ausgewiesen, vgl Frage 4).
*f1	Erwerbsstatus.
*f2	Arbeitsunfaehigkeit.
*f3_1	Dauer Fehlzeiten.
*f4	Beeinträchtigung durch Gesundheitszustand.
*f5_2	Berufliche Zukunft "nicht mehr im Beruf arbeiten".
*f6_3	Erwartung: Klaerung berufliche Situation.

fre f1 f2 f3_1 f4 f5_2 f6_3 alter.
*7 Dummies.
compute s1=f1.
recode s1 (5=1) (missing=9) (else=0).
exe.
compute s2=f2.
recode s2 (2=0).
exe.
compute s3=f3_1.
recode s3 (1 thru 4=0) (5=1).
exe.
compute s4=f4.
recode s4 (0 thru 7=0) (8 thru 10=1).
exe.
compute s5=f5_2.
exe.
compute s6=f6_3.
recode s6 (1 thru 3=0) (4 thru 5=1).
exe.
compute s7=alter.
recode s7 (lowest thru 45=1) (46 thru highest=0).
exe.
fre s1 to s7.
recode s1 to s7 (sysmis=9).
exe.
mis val s1 to s7 (9).
count mis= s1 to s7 (missing).
fre mis.


***Skalenkonstruktion (ein Missing wird durch das Strahlensatz-Prinzip ersetzt).

do if (mis=0).
	compute simbo_s=16*s1+29*s2+13*s3+8*s4+20*s5+7*s6+7*s7.
else if (mis=1) and nmis(s1).
	compute simbo_s=(29*s2+13*s3+8*s4+20*s5+7*s6+7*s7)*100/84.
else if (mis=1) and nmis(s2).
	compute simbo_s=(16*s1+13*s3+8*s4+20*s5+7*s6+7*s7)*100/71.
else if (mis=1) and nmis(s3).
	compute simbo_s=(16*s1+29*s2+8*s4+20*s5+7*s6+7*s7)*100/86.
else if (mis=1) and nmis(s4).
	compute simbo_s=(16*s1+29*s2+13*s3+20*s5+7*s6+7*s7)*100/92.
else if (mis=1) and nmis(s5).
	compute simbo_s=(16*s1+29*s2+13*s3+8*s4+7*s6+7*s7)*100/80.
else if (mis=1) and nmis(s6).
	compute simbo_s=(16*s1+29*s2+13*s3+8*s4+20*s5+7*s7)*100/93.
else if (mis=1) and nmis(s7).
	compute simbo_s=(16*s1+29*s2+13*s3+8*s4+20*s5+7*s6)*100/93.
end if.
exe.
fre simbo_s.

***Beispiel: Cut off bei 30 Punkten.
recode simbo_s (0 thru 29.99 = 0) (30 thru 100 = 1) into simbo30.
exe.
fre simbo30.